How to export Word comments to Excel, with the text each comment refers to

1Which method fits

2Copy from the Comments pane

1. On the Review tab, choose Show Comments and switch to the list view, so every comment is in the pane on the right.
2. Select the comments, press Ctrl+C, and paste into Excel.

You get names and comment text, usually in one column, with no link to the words each comment was made on. It is fine for five comments; for eighty it becomes an afternoon of tidying.

3Print the List of Markup

1. File › Print, and under Settings open the first drop-down and choose List of Markup.
2. Print to Microsoft Print to PDF.

You get every comment and tracked change with its page number, in order. But it is a document, not a table: you cannot sort it, filter it or type answers next to it, and pasting it into Excel breaks it into lines.

4A macro that writes every comment to Excel

This macro runs in Word, starts Excel, and writes one row per comment and reply: number, page, line, the commented text, the comment, author, date, status and, for replies, the comment it answers.

1. Open the document, press Alt+F11 to open the VBA editor, then Insert › Module.
2. Paste the code below.
3. Click inside ExportCommentsToExcel and press F5. Excel opens with the list.

' Writes every comment in the active document to a new Excel workbook.
Sub ExportCommentsToExcel()
    Dim doc As Document: Set doc = ActiveDocument
    If doc.Comments.Count = 0 Then
        MsgBox "This document has no comments.": Exit Sub
    End If

    Dim xl As Object, ws As Object
    Set xl = CreateObject("Excel.Application")
    Set ws = xl.Workbooks.Add.Worksheets(1)
    ws.Range("A1:I1").Value = Array("#", "Page", "Line", "Commented text", "Comment", _
                                   "Author", "Date", "Status", "Reply to #")
    ws.Columns("D:E").NumberFormat = "@"   ' so text starting with = stays text

    Dim i As Long, c As Comment
    For i = 1 To doc.Comments.Count
        Set c = doc.Comments(i)
        ws.Cells(i + 1, 1).Value = i
        ws.Cells(i + 1, 2).Value = c.Scope.Information(wdActiveEndAdjustedPageNumber)
        ws.Cells(i + 1, 3).Value = c.Scope.Information(wdFirstCharacterLineNumber)
        ws.Cells(i + 1, 4).Value = c.Scope.Text
        ws.Cells(i + 1, 5).Value = c.Range.Text
        ws.Cells(i + 1, 6).Value = c.Author
        ws.Cells(i + 1, 7).Value = c.Date
        ws.Cells(i + 1, 8).Value = StatusOf(c)
        ws.Cells(i + 1, 9).Value = ParentOf(c)
    Next i

    ws.Columns("A:I").AutoFit
    ws.Columns("D:E").ColumnWidth = 60
    ws.Range("D:E").WrapText = True
    ws.ListObjects.Add(1, ws.Range("A1").CurrentRegion).Name = "Comments"
    xl.Visible = True
End Sub

' Done raises an error in documents saved in Compatibility Mode.
Private Function StatusOf(c As Comment) As String
    On Error GoTo Unknown
    StatusOf = IIf(c.Done, "Resolved", "Open")
    Exit Function
Unknown:
    StatusOf = ""
End Function

Private Function ParentOf(c As Comment) As Variant
    ParentOf = ""
    On Error Resume Next
    If Not c.Ancestor Is Nothing Then ParentOf = c.Ancestor.Index
End Function

What it cannot do:

• Section. “3.2 Imposed floor actions” means finding the heading above each comment, which this macro does not attempt.
• Tracked changes. It reads comments only.
• Threads. Replies come out as separate rows with a “Reply to #” number, not under their comment.
• The way back. Answers typed into the sheet stay in the sheet.

Done and Ancestor need Word 2013 or later. Your organisation may block macros, in which case the editor opens but the macro will not run; saving the document as .docm is only needed if you want to keep the macro in it.

5The one-click way, free: Comment Navigator

Comment Navigator is a Word add-in for Windows. Its Export to Excel button, in the free version, writes one row per comment with the commented text, the numbered section it sits in, the page, author, date, open or resolved, and the replies kept with their thread. No macro, no security prompt, and the numbers match the ones in its review pane, so “comment 23” in the sheet is comment 23 in Word.

Pro adds tracked changes to the same list, shown in place, and a Response / Action / Responsible set of columns. Your team answers in Excel, and Import responses puts each answer back into Word as a reply under the right comment, resolving the ones marked Done. One Undo reverts the import. Pro also exports a whole folder of documents into one workbook.

Everything runs on your computer. Documents are never uploaded.

6Questions

Does this work with the new (“modern”) comments in Microsoft 365?

Yes. The macro reads them through the same Comments collection. Modern comments do not show numbers in Word, so the number column is the only numbering you will have; see how to number comments in Word.

Can I export only the open comments?

In the macro, wrap the lines inside the loop in If StatusOf(c) <> "Resolved" Then … End If and use a separate row counter. In Comment Navigator, filter the sheet on the Status column, which is an ordinary Excel table filter.

Can I get the comments from many documents at once?

Not with the macro as written. Comment Navigator Pro’s folder export puts every document in one sheet with a Document column.

Why is the page number sometimes off by one?

Page numbers come from Word’s layout of the document on your screen, which depends on the printer driver and fonts installed. Another computer can lay the same document out a line differently. That is true of every method here, including Word’s own List of Markup.